From 375b063e90697a20ca88c48417c2f47bb2df1fc3 Mon Sep 17 00:00:00 2001
From: isaacs <i@izs.me>
Date: Fri, 14 Jun 2013 06:40:09 -0700
Subject: [PATCH 1/4] Add BNF Grammar for valid version strings

Written in collaboration with @petermichaux

Closes #110
---
 semver.md | 60 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/semver.md b/semver.md
index e84a0f3..fe4ff06 100644
--- a/semver.md
+++ b/semver.md
@@ -127,6 +127,66 @@ precedence than a smaller set, if all of the preceding identifiers are equal.
 Example: 1.0.0-alpha < 1.0.0-alpha.1 < 1.0.0-alpha.beta < 1.0.0-beta <
 1.0.0-beta.2 < 1.0.0-beta.11 < 1.0.0-rc.1 < 1.0.0.
 
+Backus–Naur Form Grammar for Valid SemVer Versions
+--------------------------------------------------
+
+    <version> ::= <major> "." <minor> "." <patch>
+                | <major> "." <minor> "." <patch> "-" <pre-release>
+                | <major> "." <minor> "." <patch> "+" <build>
+                | <major> "." <minor> "." <patch> "-" <pre-release> "+" <build>
+
+    <major> ::= <non-negative integer>
+
+    <minor> ::= <non-negative integer>
+
+    <patch> ::= <non-negative integer>
+
+    <pre-release> ::= <dot-separated identifiers>
+
+    <build> ::= <dot-separated build identifiers>
+
+    <dot-separated identifiers> ::= <identifier>
+                                  | <identifier> "." <dot-separated identifiers>
+
+    <dot-separated build identifiers> ::= <build identifier>
+                                        | <build identifier> "." <dot-separated build identifiers>
+
+    <identifier> ::= <non-negative integer>
+                   | <non-numeric identifier>
+
+    <build identifier> ::= <identifier character>
+                         | <identifier character> <build identifier>
+
+    <non-numeric identifier> ::= <non-digit character>
+                               | <non-digit character> <build identifier>
+                               | <build identifier> <non-digit character>
+                               | <build identifier> <non-digit character> <build identifier>
+
+    <non-digit character> ::= <letter> | "-"
+
+    <identifier character> ::= <non-digit character> | <digit>
+
+    <non-negative integer> ::= "0"
+                             | <positive integer>
+
+    <positive integer> ::= <positive digit>
+                         | <positive digit> <digits>
+
+    <digits> ::= <digit>
+               | <digit> <digits>
+
+    <digit> ::= "0" | <positive digit>
+
+    <positive digit> ::= "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
+
+    <letter> ::= "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J"
+               | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" | "S" | "T"
+               | "U" | "V" | "W" | "X" | "Y" | "Z" | "a" | "b" | "c" | "d"
+               | "e" | "f" | "g" | "h" | "i" | "j" | "k" | "l" | "m" | "n"
+               | "o" | "p" | "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x"
+               | "y" | "z"
+
+
 Why Use Semantic Versioning?
 ----------------------------
 

From cb5632f1c2e4dab1aaca3904a0b4bc9744a94cf4 Mon Sep 17 00:00:00 2001
From: Eddie Garmon <eddie_garmon@hotmail.com>
Date: Mon, 17 Jun 2013 19:37:23 -0300
Subject: [PATCH 2/4] Improve BNF grammar

Better names, more intuitive ordering.
---
 semver.md | 67 ++++++++++++++++++++++++++++++++++---------------------
 1 file changed, 41 insertions(+), 26 deletions(-)

diff --git a/semver.md b/semver.md
index fe4ff06..e93890d 100644
--- a/semver.md
+++ b/semver.md
@@ -130,55 +130,70 @@ Example: 1.0.0-alpha < 1.0.0-alpha.1 < 1.0.0-alpha.beta < 1.0.0-beta <
 Backus–Naur Form Grammar for Valid SemVer Versions
 --------------------------------------------------
 
-    <version> ::= <major> "." <minor> "." <patch>
-                | <major> "." <minor> "." <patch> "-" <pre-release>
-                | <major> "." <minor> "." <patch> "+" <build>
-                | <major> "." <minor> "." <patch> "-" <pre-release> "+" <build>
+    <valid semver> ::= <version core>
+                     | <version core> "-" <pre-release>
+                     | <version core> "+" <build>
+                     | <version core> "-" <pre-release> "+" <build>
 
-    <major> ::= <non-negative integer>
+    <version core> ::= <major> "." <minor> "." <patch>
 
-    <minor> ::= <non-negative integer>
+    <major> ::= <numeric identifier>
 
-    <patch> ::= <non-negative integer>
+    <minor> ::= <numeric identifier>
 
-    <pre-release> ::= <dot-separated identifiers>
+    <patch> ::= <numeric identifier>
+
+    <pre-release> ::= <dot-separated pre-release identifiers>
+
+    <dot-separated pre-release identifiers> ::= <pre-release identifier>
+                                              | <pre-release identifier> "." <dot-separated pre-release identifiers>
 
     <build> ::= <dot-separated build identifiers>
 
-    <dot-separated identifiers> ::= <identifier>
-                                  | <identifier> "." <dot-separated identifiers>
-
     <dot-separated build identifiers> ::= <build identifier>
                                         | <build identifier> "." <dot-separated build identifiers>
 
-    <identifier> ::= <non-negative integer>
-                   | <non-numeric identifier>
+    <pre-release identifier> ::= <alphanumeric identifier>
+                               | <numeric identifier>
 
-    <build identifier> ::= <identifier character>
-                         | <identifier character> <build identifier>
+    <build identifier> ::= <alphanumeric identifier>
+                         | <digits>
 
-    <non-numeric identifier> ::= <non-digit character>
-                               | <non-digit character> <build identifier>
-                               | <build identifier> <non-digit character>
-                               | <build identifier> <non-digit character> <build identifier>
+    <alphanumeric identifier> ::= <letters>
+                                | <letters> <identifier characters>
+                                | <digits> <non-digits>
+                                | <digits> <non-digits> <identifier characters>
+                                | <digits> <identifier characters> <non-digits>
+                                | <digits> <identifier characters> <non-digits> <identifier characters>
+                                | "-" <identifier characters>
 
-    <non-digit character> ::= <letter> | "-"
+    <numeric identifier> ::= "0"
+                           | <positive digit>
+                           | <positive digit> <digits>
 
-    <identifier character> ::= <non-digit character> | <digit>
+    <identifier characters> ::= <identifier character>
+                              | <identifier character> <identifier characters>
 
-    <non-negative integer> ::= "0"
-                             | <positive integer>
+    <identifier character> ::= <digit>
+                             | <non-digit>
+    
+    <non-digits> ::= <non-digit>
+                   | <non-digit> <non-digits>
 
-    <positive integer> ::= <positive digit>
-                         | <positive digit> <digits>
+    <non-digit> ::= <letter>
+                  | "-"
 
     <digits> ::= <digit>
                | <digit> <digits>
 
-    <digit> ::= "0" | <positive digit>
+    <digit> ::= "0" 
+              | <positive digit>
 
     <positive digit> ::= "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
 
+    <letters> ::= <letter>
+                | <letter> <letters>
+
     <letter> ::= "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J"
                | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" | "S" | "T"
                | "U" | "V" | "W" | "X" | "Y" | "Z" | "a" | "b" | "c" | "d"

From 9e6ab3ecdb3550e2fe66403f6da95f0cdb94eaf4 Mon Sep 17 00:00:00 2001
From: isaacs <i@izs.me>
Date: Wed, 19 Jun 2013 14:12:26 -0700
Subject: [PATCH 3/4] bnf: Simplify 'alphanumeric identifier'

---
 semver.md | 15 ++++++---------
 1 file changed, 6 insertions(+), 9 deletions(-)

diff --git a/semver.md b/semver.md
index e93890d..f3bc14e 100644
--- a/semver.md
+++ b/semver.md
@@ -159,13 +159,10 @@ Backus–Naur Form Grammar for Valid SemVer Versions
     <build identifier> ::= <alphanumeric identifier>
                          | <digits>
 
-    <alphanumeric identifier> ::= <letters>
-                                | <letters> <identifier characters>
-                                | <digits> <non-digits>
-                                | <digits> <non-digits> <identifier characters>
-                                | <digits> <identifier characters> <non-digits>
-                                | <digits> <identifier characters> <non-digits> <identifier characters>
-                                | "-" <identifier characters>
+    <alphanumeric identifier> ::= <non-digit>
+                                | <non-digit> <identifier characters>
+                                | <identifier characters> <non-digit>
+                                | <identifier characters> <non-digit> <identifier characters>
 
     <numeric identifier> ::= "0"
                            | <positive digit>
@@ -176,7 +173,7 @@ Backus–Naur Form Grammar for Valid SemVer Versions
 
     <identifier character> ::= <digit>
                              | <non-digit>
-    
+
     <non-digits> ::= <non-digit>
                    | <non-digit> <non-digits>
 
@@ -186,7 +183,7 @@ Backus–Naur Form Grammar for Valid SemVer Versions
     <digits> ::= <digit>
                | <digit> <digits>
 
-    <digit> ::= "0" 
+    <digit> ::= "0"
               | <positive digit>
 
     <positive digit> ::= "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

From 5f00f5717cf0c7bbcd1299d2b24656f58f5ce0af Mon Sep 17 00:00:00 2001
From: isaacs <i@izs.me>
Date: Wed, 19 Jun 2013 16:59:46 -0700
Subject: [PATCH 4/4] bnf: Remove unused 'letters', 'non-digits'

via: @EddieGarmon
---
 semver.md | 6 ------
 1 file changed, 6 deletions(-)

diff --git a/semver.md b/semver.md
index f3bc14e..4cb94ce 100644
--- a/semver.md
+++ b/semver.md
@@ -174,9 +174,6 @@ Backus–Naur Form Grammar for Valid SemVer Versions
     <identifier character> ::= <digit>
                              | <non-digit>
 
-    <non-digits> ::= <non-digit>
-                   | <non-digit> <non-digits>
-
     <non-digit> ::= <letter>
                   | "-"
 
@@ -188,9 +185,6 @@ Backus–Naur Form Grammar for Valid SemVer Versions
 
     <positive digit> ::= "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
 
-    <letters> ::= <letter>
-                | <letter> <letters>
-
     <letter> ::= "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J"
                | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" | "S" | "T"
                | "U" | "V" | "W" | "X" | "Y" | "Z" | "a" | "b" | "c" | "d"